betty/lpc2220_rom.ld

   1 /*
   2  * lpc2220_rom.ld - linker script for the lpc2220 device (->rom)
   3  *
   4  * author: hackbard@hackdaworld.org
   5  *
   6  */
   7
   8 /* memory definitions */
   9
  10 MEMORY {
  11         FLASH_BANK0 (rx) : ORIGIN = 0x80000000, LENGTH = 0x00100000
  12         FLASH_BANK2 (rx) : ORIGIN = 0x82000000, LENGTH = 0x00100000
  13         RAM (rw) : ORIGIN = 0x40000000, LENGTH = 0x00010000 - (4 * 1024)
  14 }
  15
  16 /* section definitions */
  17
  18 SECTIONS {
  19
  20         /* startup and user code (.text) */
  21         .text : {
  22                 startup.o(.text)
  23                 *(.text)
  24                 *(.glue_7)
  25                 *(.glue_7t)
  26         } > FLASH_BANK0
  27
  28         . = ALIGN(4);
  29
  30         /* read only data */
  31         .rodata : { *(.rodata*) } > FLASH_BANK0
  32
  33         . = ALIGN(4);
  34
  35         /* define text end symbol */
  36         _etext = .;
  37         PROVIDE(etext = .);
  38
  39         /* initialized data */
  40         .data : {
  41                 _data = .;
  42                 *(.data)
  43         } > RAM AT > FLASH_BANK0
  44
  45         . = ALIGN(4);
  46
  47         /* define data end symbol */
  48         _edata = .;
  49         PROVIDE(edata = .);
  50
  51         /* uninitialized data */
  52         .bss (NOLOAD) : { *(.bss) } > RAM
  53
  54         /* define bss end symbol */
  55         _bss_end = .;
  56         PROVIDE(bss_end = .);
  57 }
  58