;
; thermo - getting temperature using analog comparator
;
; author: hackbard@hackdaworld.org
;

; specify device
.include "../include/tn2313def.inc"

;
; interrupts
;

; RESET
rjmp INIT

; INT0
reti

; INT1
reti

; T1 CAPT1
reti

; T1 COMP A
reti

; T1 OVF1
rjmp T1_OVERFLOW

; T0 OVF0
reti

; UART RX
reti

; UART UDRE
reti

; UART TX
reti

; ANA COMP
rjmp ANA_COMP

; PCINT
reti

; T1 COMP B
reti

; T0 COMP A
reti

; T0 COMP B
reti

; USI START
reti

; USI OVF
reti

; EE READY
reti

; WDT OVF
reti

;
; init function
;

INIT:

	; stackpointer
	ldi r16,low(RAMEND)
	out SPL,r16

	; zero to register 0
	ldi r17,0
	mov r0,r17

	; uart init
	UART_INIT:

		ldi r16,51 ; 9k6 bps @ 8mhz
		out UBRRL, r16
		out UBRRH, r0

		ldi r16,(1<<UCSZ0)|(1<<UCSZ1) ; 8n1
		out UCSRC,r16;

		sbi UCSRB,TXEN ; enable tx

	; timer init
	TIMER_INIT:

		; prescaler 64
		ldi r16,(1<<CS10)|(1<<CS11)
		out TCCR1B,r16

	; analog comparator init
	ANA_COMP_INIT:

		; interrupt if voltage is higher
		; enable input capture function ot tc1
		ldi r16,(1<<ACIS0)|(1<<ACIS1)
		out ACSR,r16

	; output for rc element
	RC_PIN_INIT:
		sbi DDRD,DDD2 ; pin 2 port d is output


MAIN:

	; status register
	ldi r31,0

	; decharge rc pin
	cbi PORTD,PORTD2

	; enable overflow interrupt
	ldi r17,(1<<TOIE1)	
	out TIMSK,r17

	; global interrupt enable
	sei

	; loop forever
	MAIN_LOOP:

	; loop
	rjmp MAIN_LOOP

;
; analog comparator interrupt routine
;

ANA_COMP:

	; immediately take away the clock
	out TCCR1B,r0

	; disable comparator + del possible interrupt flag
	cbi ACSR,ACIE

	; pull low the rc element
	cbi PORTD,PORTD2

	; read the captured value
	in r19,TCNT1L
	in r18,TCNT1H

	LOOP_ONE:
		sbis UCSRA,UDRE
		rjmp LOOP_ONE
		out UDR,r18
	LOOP_TWO:
		sbis UCSRA,UDRE
		rjmp LOOP_TWO
		out UDR,r19

	; reset timer counter
	out TCNT1H,r0
	out TCNT1L,r0

	; clear possible overflow flag
	ldi r17,(1<<TOV1)
	out TIFR,r17

	; enable the counter
	ldi r17,(1<<CS10)|(1<<CS11)
	out TCCR1B,r17

	reti

;
; timer 1 overflow interrupt function
;

T1_OVERFLOW:

	; check whether second run
	cpi r31,4
	brne MARK_2ND_RUN

	; reset to a first run
	ldi r31,0

	; enable analog comparator interrupt + del possible interrupt flags
	sbi ACSR,ACIE
	sbi ACSR,ACI

	; pull rc element high
	sbi PORTD,PORTD2

	reti

	MARK_2ND_RUN:
		inc r31
		reti